:: DVD-RW USES -ERASE PARAMETER
:: DVD+RW DOES NOT USE -ERASE PARAMETER
:: USES DVDBURN.EXE DIRUSE.EXE MKISOFS.EXE
@echo off
color 1f
ECHO **********************
ECHO.
ECHO STARTING DVD+RW BACKUP
ECHO.
ECHO **********************
rd /s /q D:\storage\backup
del D:\storage\DVDRW.iso
md D:\storage\backup\docs
md D:\storage\backup\data
md D:\storage\backup\bin
xcopy /C /H /E /R /Y /EXCLUDE:c:\bin\DVD_exclude.txt "%USERPROFILE%\My Documents\*" D:\storage\backup\docs
xcopy /C /H /E /R /Y C:\data\* D:\storage\backup\data
xcopy /C /H /E /R /Y C:\bin\* D:\storage\backup\bin
C:\bin\mkisofs.exe -v -J -R -l -o D:\storage\DVDRW.iso D:\storage\backup
for /f "tokens=1,2" %%u in ('date /t') do set d=%%v
for /f "tokens=1" %%u in ('time /t') do set t=%%u
if "%t:~1,1%"==":" set t=0%t%
set timestr=%d:~6,4%%d:~0,2%%d:~3,2%%t:~0,2%%t:~3,2%
echo DVD+RW Backup start at %timestr% >> C:\bin\logs\DVD+RW_backup_%COMPUTERNAME%.txt
C:\bin\DVDburn.exe f: D:\storage\DVDRW.iso >> C:\bin\logs\DVD+RW_backup_%COMPUTERNAME%.txt
echo DVD+RW MEDIA BURNED ON %timestr% >> C:\bin\logs\DVD+RW_backup_%COMPUTERNAME%.txt
echo By %USERNAME% on %COMPUTERNAME% >> C:\bin\logs\DVD+RW_backup_%COMPUTERNAME%.txt
ping -n 15 127.0.0.1 > nul
C:\bin\diruse f:\ /M /* >> C:\bin\logs\DVD+RW_backup_%COMPUTERNAME%.txt
del D:\storage\DVDRW.iso
rd /s /q D:\storage\backup